@echo off
if "%OS%" == "Windows_NT" setlocal
rem ---------------------------------------------------------------------------
rem Stop script for the WILLOW Server
rem
rem $Id: shutdown.bat,v 1.3 2002/08/04 18:19:43 patrickl Exp $
rem ---------------------------------------------------------------------------

rem Guess WILLOW_HOME if not defined
if not "%WILLOW_HOME%" == "" goto gotHome
set WILLOW_HOME=.
if exist "%WILLOW_HOME%\bin\willow.bat" goto okHome
set WILLOW_HOME=..
:gotHome
if exist "%WILLOW_HOME%\bin\willow.bat" goto okHome
echo The WILLOW_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto end
:okHome

set EXECUTABLE=%WILLOW_HOME%\bin\willow.bat

rem Check that target executable exists
if exist "%EXECUTABLE%" goto okExec
echo Cannot find %EXECUTABLE%
echo This file is needed to run this program
goto end
:okExec

rem Get remaining unshifted command line arguments and save them in the
set CMD_LINE_ARGS=
:setArgs
if ""%1""=="""" goto doneSetArgs
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
shift
goto setArgs
:doneSetArgs

call "%EXECUTABLE%" stop %CMD_LINE_ARGS%

:end
